几行代码搞定Flash应用的多语言实时切换问题-白红宇

在《》文中批评了WPF/SL的数据绑定机制，拿的是Flex的数据绑定与其对比。本文介绍应用Flex的数据绑定来解决一个实际问题——多语言实时切换的问题，以说明简洁的数据绑定机制解决问题是多么的优雅。

需要解决的问题：

有一个语言选择下拉菜单，用户选择不同的语言，自动去服务器获取语言资源，然后自动更新界面上的显示。

这个问题看起来很复杂，传统的解决办法是在涉及到多语言的界面处侦听语言切换的事件，然后更新自己，这样的做法零碎冗长。使用数据绑定是个自然有效的方法。

核心类只1个：

import common.RpcRequest;

public dynamic class Lang extends Object
{
    [Bindable]
    public static var instance:Lang = new Lang;
    public function getString(key:String, defaultString:String = null):String
    {
        if(this.hasOwnProperty(key)==false)
        {
            return defaultString ? defaultString : key;
        }
        else
        {
            return this[key];
        }
    }
    public static function loadRemote(url:String, callback:Function = null):void
    {
        new RpcRequest(url, null,
            function(obj:Object):void
            {
                loadXml(new XML(obj));
                if(callback != null) callback();
            }
        );
    }
    public static function loadXml(xml:XML):void
    {
        if(xml == null) return;
        var lang:Lang = new Lang();
        for each(var node: XML in xml.item)
        {
            lang[node.@key]=String(node.@value);
        }
        instance = lang;
    }
}

使用loadRemote去加载资源，成功的话自动更新绑定源instance。如果设置了回调方法，可以传入回调方法来干其它的事情。

资源文件举例：

<lang>
<item key="Help" value="Help Tips" />"
<item key="MoreInfo" value="More Informations" />"
<item key="FlipToFront" value="Flip to Front Cover" />"
…
</lang>

使用：

toolTip="{RunTime.fullScreen
?Lang.instance.getString('ExitFullScreen','Exit Full Screen')
:Lang.instance.getString('FullScreen','Full Screen')}"

更进一步，可以将类名Lang简化为l，将instance简化为_，将getString简化为s。这样代码又可以简洁一些。

实时切换语言一行代码搞定：

Lang.loadRemote(langUrl);

====

总结：

（1）简洁吗？简洁！

（2）需要学新东西吗？不需要！

（3）需要配置吗？不需要！

（4）对比是不是觉得WPF/SL的数据绑定过度设计了？是的！

本文转自xiaotie博客园博客，原文链接http://www.cnblogs.com/xiaotie/archive/2011/05/29/2062032.html如需转载请自行联系原作者

xiaotie 集异璧实验室(GEBLAB)